Содержание Назад Вперед

Непараметрическая поверхность

#
# $Id: surface1.demo 3.38.2.6 1992/11/14 02:25:21 woo Exp $
#
set samples 21
set isosample 11
set xlabel "X axis" -3,-2
set ylabel "Y axis" 3,-2
set zlabel "Z axis" -5
set title "3D gnu plot demo"
set label 1 "This is the surface boundary" at -10,-5,150 center
set arrow 1 from -10,-5,120 to -10,0,0 nohead
set arrow 2 from -10,-5,120 to 10,0,0 nohead
set arrow 3 from -10,-5,120 to 0,10,0 nohead
set arrow 4 from -10,-5,120 to 0,-10,0 nohead
set xrange [-10:10]
set yrange [-10:10]
splot x*y

set noarrow
set nolabel
set grid
splot x**2+y**2, x**2-y**2

rep x*y

rep (x**3+y**3)/10

set ticslevel 0.0
set title "3D gnu plot demo ( ticslevel = 0.0 )"
rep

set ticslevel 2.0
set title "3D gnu plot demo ( ticslevel = 2.0 )"
rep

set ticslevel 0.5
set title "3D gnu plot demo ( ticslevel = 0.5 )"
rep

set title "3D gnu plot demo"
set nogrid
splot x*y with points

set noxtics
set noytics
set xrange [-1:1]
set yrange [-1:1]
set title "Surfaces with no grid or tics"
splot x*y with lines, x**2*y**3 with dots, x**3*y*2 with points

set xtics ("low" -3, "mid" 0, "high" 3)
set ytics -2,0.5,2
set xrange [-3:3]
set yrange [-3:3]
set log z
set title "Surfaces with z log scale"
splot x**2*y**2 + 2, x**2*y**4 + 2, x**4*y**2 + 2

set nolog z
set xtics
set ytics
set xrange [-1:1]
set yrange [-1:1]
set samples 51
set isosample 21
set dummy u,v
set title "3D gnu plot demo"
splot u*v / (u**2 + v**2 + 0.1)

splot [x=-3:3] [y=-3:3] sin(x) * cos(y)

set zrange [-0.35:0.35]
replot

set title "Sinc function"
set zrange [-1:1]
set label 1 "This is equal to 1" at -5,-2,0.75 right
set arrow 1 from -5,-2.1,0.75 to 0,0,1
sinc(u,v) = sin(sqrt(u**2+v**2)) / sqrt(u**2+v**2)
splot [-5:5.01] [-5:5.01] sinc(u,v)

set view 70,20,1
set zrange [-0.5:1.0]
set ztics -1,0.25,1
set label 1 "This is equal to 1" at -5,-2,1.5 centre
set arrow 1 from -5,-2.1,1.4 to 0,0,1
splot [-12:12.01] [-12:12.01] sinc(u,v)

set noarrow
set ztics
set nolabel
set log
set auto
set title "This has logarithmic scale"
splot [x=1:15] [y=1:15] x**2+y**2

set nolog
set xrange [0:15]
set yrange [0:15]
set auto
set zrange [-0.6:0.7]
set data style lines
set title "Data grid plotting"
set parametric
splot "glass.dat"

splot "glass.dat" using 3:2:1

set zrange [-1.2:1.2]
set noparametric
splot "glass.dat" using 1, "glass.dat" using 2, "glass.dat" using 3

set param
set title "Test of spherical transform"
set mapp sphe
splot "glass.dat"

#
# Очистка:
#
set nopar
set mapp cart
set samples 100
set isosamples 10
set view 60,30,1,1
set xrange [-10:10]
set yrange [-10:10]
set zrange [-10:10]
set auto
set title "" 0,0
set xlabel "" 0,0
set ylabel "" 0,0
set zlabel "" 0,0
# мандельбротовская ошибка
set isosamples 100
set hidden3d
compl(a,b)=a*{1,0}+b*{0,1}
mand(z,a,n) = n<=0 || abs(z)>100 ? 1:mand(z*z+a,a,n-1)+1
splot [-2:1][-1.5:1.5] mand({0,0},compl(x,y),50)     
# TANAKA Masaki  (Tokyo Institute of technology)
#                 masaki@isea.is.titech.ac.jp